RxFTP Kütüphanesi - Örnek Uygulama
    ==================================

    "RxFTP" kütüphanesindeki işlevler kullanılarak oluşturulan
    örnek bir uygulama, izleyen satırlarda yer aldığı gibidir.

    /*==============================================================*/
    /*   cmd/reply oturumu ile bir dosyayı gönderen basit RxFTP     */
    /*   örnek uygulaması.                                          */
    /*==============================================================*/

    /* Değişkenlerin tanımlanması                                   */

     server = '127.0.0.1'           /* IP bulunağı ya da sunucu adı */
     userid = 'remote_user_ID'
     passwd = 'password_of_remote_user'
     trclog = 'logfile.txt'         /* İzleme dosyasının adı       */
     RC     = 0                     /* Dönüş değeri sıfır (0)      */

 
    /* RxFTP kütüphanesinin sorgulanarak kurulması işlemi.             */

    If RxFuncQuery('FtpDropFuncs') then
      Do
         RC = RxFuncAdd('FtpLoadFuncs', 'rxftp', 'FtpLoadFuncs')
         RC = FtpLoadFuncs()
      End

    If RC <> 0 then
     Do
        Say ' *** FTP işlevleri yüklenemedi.'
        Exit RC
     End

    /* FTP buyruklarının izlenmesinin başlatılması ve yanıtların       */
    /* kayıt altına alınması işlemi.                                   */
    RC = FtpTrace()
    RC = FtpTraceLog( trclog, '1')
    If RC = 0 then
        Say ' Yanıtlar dosyaya yazılıyor: 'trclog'.'
    Else
        Say ' Yanıtların yazılmasında sorun var: 'trclog' olasıdır.'

    /* Uzak ana bilgisayar ve kullanıcı isimlerinin oturum için         */
    /* hazırlanması işlemi yapılıyor.                                   */
    RC = FtpSetUser(server, userid, passwd)
    If RC = 1 then
        Say ' Bağlantı için ayarlar kaydedildi.'
    Else
        Call Terminate " *** Bağlantı için ayarlarda bir hata oluştu."

    /* S/390 FTP sunucuları etkin kipte bulunmaya gereksinim duyuyor. */
    RC = FtpSetActiveMode('1')
    If RC = 1 then
        Say ' Etkin kip ayarlandı.'
    Else
        Call Terminate " *** Etkin kip ayarlarında hata oluştu."

    /* Bir ASCII dosyasının karşı FTP sunucusuna aktarımı. */
    RC = FtpPut('sample.rex', 'sample.put', 'ASCII')
    If RC = 0 then
        Call Terminate ' Dosya başarılı bir şekilde aktarıldı. '
    Else
        Call Terminate " *** Dosya aktarılamadı."

    /* Dosya aktarımı sonlandırılıyor.                                  */
    Terminate:
      Parse Arg Message
      Say Message
      Call FtpLogoff   /* Log off (QUIT buyruğu sunucuya gönderiliyor.  */
      Call FtpTraceLogOff  /* Seyir sonlandırılıyor. Seyir dosyasy kapalı. */
      Call FtpTrace
      Call FtpDropFuncs    /* İşlev paketi uzaklaştırılıyor.            */

    Exit RC